[Oisf-devel] Suricata 1.0.0 released

[Robert Kerr]

On Thu, 2010-07-01 at 17:48 +0200, Victor Julien wrote:
> The OISF development team is proud to announce Suricata 1.0.0, the first
> stable release of Suricata, the Open Source Intrusion Detection and
> Prevention engine.

Congrats guys!

Attached are a couple of gentoo ebuilds for suricata, one for the stable
version and one to build a snapshot of the latest git. Hope they're
useful to someone...

-- 
 Robert Kerr
-------------- next part --------------
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=3

DESCRIPTION="Open Source Next Generation Intrusion Detection and Prevention Engine"
HOMEPAGE="http://www.openinfosecfoundation.org/"
SRC_URI="http://www.openinfosecfoundation.org/download/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="x86 amd64"
IUSE="nfqueue perfprofiling prelude"

DEPEND="virtual/libpcap
	>=dev-libs/libpcre-6.5
	dev-libs/libyaml
	sys-libs/libcap-ng
	sys-libs/zlib
	prelude? ( dev-libs/libprelude )
	nfqueue? ( net-libs/libnetfilter_queue )"
RDEPEND="${DEPEND}"

src_configure() {
	econf \
		$(use_enable perfprofiling profiling) \
		$(use_enable prelude) \
		$(use_enable nfqueue) \
		|| die "econf failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "make install failed"

	dodoc doc/README doc/NEWS doc/AUTHORS ChangeLog

	insinto /etc/suricata
	doins classification.config \
	      suricata.yaml
	
	keepdir /etc/suricata/rules/
	keepdir /var/log/suricata
}

-------------- next part --------------
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=3

inherit autotools git

EGIT_REPO_URI="git://phalanx.openinfosecfoundation.org/oisf.git"

DESCRIPTION="Open Source Next Generation Intrusion Detection and Prevention Engine"
HOMEPAGE="http://www.openinfosecfoundation.org/"
SRC_URI=""

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86 ~amd64"
IUSE="nfqueue perfprofiling prelude"

DEPEND="virtual/libpcap
	dev-libs/libpcre
	dev-libs/libyaml
	sys-libs/libcap-ng
	sys-libs/zlib
	prelude? ( dev-libs/libprelude )
	nfqueue? ( net-libs/libnetfilter_queue )"
RDEPEND="${DEPEND}"

src_unpack() {
	git_src_unpack
	cd "${S}"
	./autogen.sh
}

src_configure() {
	econf \
		$(use_enable perfprofiling profiling) \
		$(use_enable prelude) \
		$(use_enable nfqueue) \
		|| die "econf failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "make install failed"

	dodoc doc/README doc/NEWS doc/AUTHORS ChangeLog

	insinto /etc/suricata
	doins classification.config \
	      suricata.yaml
	
	keepdir /etc/suricata/rules/
	keepdir /var/log/suricata
}